@echo off
SETLOCAL
SET APP_ROOT=%~dp0
IF "%APP_ROOT:~-1%"=="\" SET APP_ROOT=%APP_ROOT:~0,-1%

SET PROGRAM_DIR=%APP_ROOT%\Programmdateien
SET NODE_EXE=%PROGRAM_DIR%\node\node.exe
SET DIST_DIR=%PROGRAM_DIR%\dist
SET LAUNCHER_JS=%PROGRAM_DIR%\launcher.js

IF NOT EXIST "%NODE_EXE%" (
    echo FEHLER: node.exe nicht gefunden in %PROGRAM_DIR%\node\
    echo Bitte ZIP-Datei erneut vollstaendig entpacken.
    pause
    exit /b 1
)
IF NOT EXIST "%DIST_DIR%\index.html" (
    echo FEHLER: Programmdateien\dist\index.html fehlt. Bitte ZIP-Datei erneut vollstaendig entpacken.
    pause
    exit /b 1
)
IF NOT EXIST "%LAUNCHER_JS%" (
    echo FEHLER: launcher.js fehlt. Bitte ZIP-Datei erneut vollstaendig entpacken.
    pause
    exit /b 1
)

REM S.O.L.O. WorkManager startet lokal/offline ueber localhost.
REM Der Launcher sucht automatisch einen freien lokalen Port und oeffnet den Standardbrowser.
START "" /B "%NODE_EXE%" "%LAUNCHER_JS%" "%DIST_DIR%" "%APP_ROOT%"
ENDLOCAL
